dYdX

1/*
2    Copyright 2019 dYdX Trading Inc.
3    Licensed under the Apache License, Version 2.0 (the "License");
4    you may not use this file except in compliance with the License.
5    You may obtain a copy of the License at
6    http://www.apache.org/licenses/LICENSE-2.0
7    Unless required by applicable law or agreed to in writing, software
8    distributed under the License is distributed on an "AS IS" BASIS,
9    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
10    See the License for the specific language governing permissions and
11    limitations under the License.
12*/
13
14pragma solidity 0.5.7;
15pragma experimental ABIEncoderV2;
16
17import { MultiSig } from "./MultiSig.sol";
18
19
20/**
21 * @title DelayedMultiSig
22 * @author dYdX
23 *
24 * Multi-Signature Wallet with delay in execution.
25 * Allows multiple parties to execute a transaction after a time lock has passed.
26 * Adapted from Amir Bandeali's MultiSigWalletWithTimeLock contract.
27 * Logic Changes:
28 *  - Only owners can execute transactions
29 *  - Require that each transaction succeeds
30 *  - Added function to execute multiple transactions within the same Ethereum transaction
31 */
32contract DelayedMultiSig is
33    MultiSig
34{
35    // ============ Events ============
36
37    event ConfirmationTimeSet(uint256 indexed transactionId, uint256 confirmationTime);
38    event TimeLockChange(uint32 secondsTimeLocked);
39
40    // ============ Storage ============
41
42    uint32 public secondsTimeLocked;
43    mapping (uint256 => uint256) public confirmationTimes;
44
45    // ============ Modifiers ============
46
47    modifier notFullyConfirmed(
48        uint256 transactionId
49    ) {
50        require(
51            !isConfirmed(transactionId),
52            "TX_FULLY_CONFIRMED"
53        );
54        _;
55    }
56
57    modifier fullyConfirmed(
58        uint256 transactionId
59    ) {
60        require(
61            isConfirmed(transactionId),
62            "TX_NOT_FULLY_CONFIRMED"
63        );
64        _;
65    }
66
67    modifier pastTimeLock(
68        uint256 transactionId
69    ) {
70        require(
71            block.timestamp >= confirmationTimes[transactionId] + secondsTimeLocked,
72            "TIME_LOCK_INCOMPLETE"
73        );
74        _;
75    }
76
77    // ============ Constructor ============
78
79    /**
80     * Contract constructor sets initial owners, required number of confirmations, and time lock.
81     *
82     * @param  _owners             List of initial owners.
83     * @param  _required           Number of required confirmations.
84     * @param  _secondsTimeLocked  Duration needed after a transaction is confirmed and before it
85     *                             becomes executable, in seconds.
86     */
87    constructor (
88        address[] memory _owners,
89        uint256 _required,
90        uint32 _secondsTimeLocked
91    )
92        public
93        MultiSig(_owners, _required)
94    {
95        secondsTimeLocked = _secondsTimeLocked;
96    }
97
98    // ============ Wallet-Only Functions ============
99
100    /**
101     * Changes the duration of the time lock for transactions.
102     *
103     * @param  _secondsTimeLocked  Duration needed after a transaction is confirmed and before it
104     *                             becomes executable, in seconds.
105     */
106    function changeTimeLock(
107        uint32 _secondsTimeLocked
108    )
109        public
110        onlyWallet
111    {
112        secondsTimeLocked = _secondsTimeLocked;
113        emit TimeLockChange(_secondsTimeLocked);
114    }
115
116    // ============ Admin Functions ============
117
118    /**
119     * Allows an owner to confirm a transaction.
120     * Overrides the function in MultiSig.
121     *
122     * @param  transactionId  Transaction ID.
123     */
124    function confirmTransaction(
125        uint256 transactionId
126    )
127        public
128        ownerExists(msg.sender)
129        transactionExists(transactionId)
130        notConfirmed(transactionId, msg.sender)
131        notFullyConfirmed(transactionId)
132    {
133        confirmations[transactionId][msg.sender] = true;
134        emit Confirmation(msg.sender, transactionId);
135        if (isConfirmed(transactionId)) {
136            setConfirmationTime(transactionId, block.timestamp);
137        }
138    }
139
140    /**
141     * Allows an owner to execute a confirmed transaction.
142     * Overrides the function in MultiSig.
143     *
144     * @param  transactionId  Transaction ID.
145     */
146    function executeTransaction(
147        uint256 transactionId
148    )
149        public
150        ownerExists(msg.sender)
151        notExecuted(transactionId)
152        fullyConfirmed(transactionId)
153        pastTimeLock(transactionId)
154    {
155        Transaction storage txn = transactions[transactionId];
156        txn.executed = true;
157        bool success = externalCall(
158            txn.destination,
159            txn.value,
160            txn.data.length,
161            txn.data
162        );
163        require(
164            success,
165            "TX_REVERTED"
166        );
167        emit Execution(transactionId);
168    }
169
170    /**
171     * Allows an owner to execute multiple confirmed transactions.
172     *
173     * @param  transactionIds  List of transaction IDs.
174     */
175    function executeMultipleTransactions(
176        uint256[] memory transactionIds
177    )
178        public
179        ownerExists(msg.sender)
180    {
181        for (uint256 i = 0; i < transactionIds.length; i++) {
182            executeTransaction(transactionIds[i]);
183        }
184    }
185
186    // ============ Helper Functions ============
187
188    /**
189     * Sets the time of when a submission first passed.
190     */
191    function setConfirmationTime(
192        uint256 transactionId,
193        uint256 confirmationTime
194    )
195        internal
196    {
197        confirmationTimes[transactionId] = confirmationTime;
198        emit ConfirmationTimeSet(transactionId, confirmationTime);
199    }
200}

JavaScript Tests