Rari Capital

1// SPDX-License-Identifier: AGPL-3.0-only
2pragma solidity 0.8.10;
3
4import {Auth} from "solmate/auth/Auth.sol";
5import {ERC4626} from "solmate/mixins/ERC4626.sol";
6
7import {SafeCastLib} from "solmate/utils/SafeCastLib.sol";
8import {SafeTransferLib} from "solmate/utils/SafeTransferLib.sol";
9import {FixedPointMathLib} from "solmate/utils/FixedPointMathLib.sol";
10
11import {WETH} from "solmate/tokens/WETH.sol";
12import {ERC20} from "solmate/tokens/ERC20.sol";
13import {Strategy, ERC20Strategy, ETHStrategy} from "./interfaces/Strategy.sol";
14
15/// @title Rari Vault (rvToken)
16/// @author Transmissions11 and JetJadeja
17/// @notice Flexible, minimalist, and gas-optimized yield
18/// aggregator for earning interest on any ERC20 token.
19contract Vault is ERC4626, Auth {
20    using SafeCastLib for uint256;
21    using SafeTransferLib for ERC20;
22    using FixedPointMathLib for uint256;
23
24    /*///////////////////////////////////////////////////////////////
25                                 CONSTANTS
26    //////////////////////////////////////////////////////////////*/
27
28    /// @notice The maximum number of elements allowed on the withdrawal stack.
29    /// @dev Needed to prevent denial of service attacks by queue operators.
30    uint256 internal constant MAX_WITHDRAWAL_STACK_SIZE = 32;
31
32    /*///////////////////////////////////////////////////////////////
33                                IMMUTABLES
34    //////////////////////////////////////////////////////////////*/
35
36    /// @notice The underlying token the Vault accepts.
37    ERC20 public immutable UNDERLYING;
38
39    /// @notice The base unit of the underlying token and hence rvToken.
40    /// @dev Equal to 10 ** decimals. Used for fixed point arithmetic.
41    uint256 internal immutable BASE_UNIT;
42
43    /// @notice Creates a new Vault that accepts a specific underlying token.
44    /// @param _UNDERLYING The ERC20 compliant token the Vault should accept.
45    constructor(ERC20 _UNDERLYING)
46        ERC4626(
47            // Underlying token
48            _UNDERLYING,
49            // ex: Rari Dai Stablecoin Vault
50            string(abi.encodePacked("Rari ", _UNDERLYING.name(), " Vault")),
51            // ex: rvDAI
52            string(abi.encodePacked("rv", _UNDERLYING.symbol()))
53        )
54        Auth(Auth(msg.sender).owner(), Auth(msg.sender).authority())
55    {
56        UNDERLYING = _UNDERLYING;
57
58        BASE_UNIT = 10**decimals;
59
60        // Prevent minting of rvTokens until
61        // the initialize function is called.
62        totalSupply = type(uint256).max;
63    }
64
65    /*///////////////////////////////////////////////////////////////
66                           FEE CONFIGURATION
67    //////////////////////////////////////////////////////////////*/
68
69    /// @notice The percentage of profit recognized each harvest to reserve as fees.
70    /// @dev A fixed point number where 1e18 represents 100% and 0 represents 0%.
71    uint256 public feePercent;
72
73    /// @notice Emitted when the fee percentage is updated.
74    /// @param user The authorized user who triggered the update.
75    /// @param newFeePercent The new fee percentage.
76    event FeePercentUpdated(address indexed user, uint256 newFeePercent);
77
78    /// @notice Sets a new fee percentage.
79    /// @param newFeePercent The new fee percentage.
80    function setFeePercent(uint256 newFeePercent) external requiresAuth {
81        // A fee percentage over 100% doesn't make sense.
82        require(newFeePercent <= 1e18, "FEE_TOO_HIGH");
83
84        // Update the fee percentage.
85        feePercent = newFeePercent;
86
87        emit FeePercentUpdated(msg.sender, newFeePercent);
88    }
89
90    /*///////////////////////////////////////////////////////////////
91                        HARVEST CONFIGURATION
92    //////////////////////////////////////////////////////////////*/
93
94    /// @notice Emitted when the harvest window is updated.
95    /// @param user The authorized user who triggered the update.
96    /// @param newHarvestWindow The new harvest window.
97    event HarvestWindowUpdated(address indexed user, uint128 newHarvestWindow);
98
99    /// @notice Emitted when the harvest delay is updated.
100    /// @param user The authorized user who triggered the update.
101    /// @param newHarvestDelay The new harvest delay.
102    event HarvestDelayUpdated(address indexed user, uint64 newHarvestDelay);
103
104    /// @notice Emitted when the harvest delay is scheduled to be updated next harvest.
105    /// @param user The authorized user who triggered the update.
106    /// @param newHarvestDelay The scheduled updated harvest delay.
107    event HarvestDelayUpdateScheduled(address indexed user, uint64 newHarvestDelay);
108
109    /// @notice The period in seconds during which multiple harvests can occur
110    /// regardless if they are taking place before the harvest delay has elapsed.
111    /// @dev Long harvest windows open the Vault up to profit distribution slowdown attacks.
112    uint128 public harvestWindow;
113
114    /// @notice The period in seconds over which locked profit is unlocked.
115    /// @dev Cannot be 0 as it opens harvests up to sandwich attacks.
116    uint64 public harvestDelay;
117
118    /// @notice The value that will replace harvestDelay next harvest.
119    /// @dev In the case that the next delay is 0, no update will be applied.
120    uint64 public nextHarvestDelay;
121
122    /// @notice Sets a new harvest window.
123    /// @param newHarvestWindow The new harvest window.
124    /// @dev The Vault's harvestDelay must already be set before calling.
125    function setHarvestWindow(uint128 newHarvestWindow) external requiresAuth {
126        // A harvest window longer than the harvest delay doesn't make sense.
127        require(newHarvestWindow <= harvestDelay, "WINDOW_TOO_LONG");
128
129        // Update the harvest window.
130        harvestWindow = newHarvestWindow;
131
132        emit HarvestWindowUpdated(msg.sender, newHarvestWindow);
133    }
134
135    /// @notice Sets a new harvest delay.
136    /// @param newHarvestDelay The new harvest delay to set.
137    /// @dev If the current harvest delay is 0, meaning it has not
138    /// been set before, it will be updated immediately, otherwise
139    /// it will be scheduled to take effect after the next harvest.
140    function setHarvestDelay(uint64 newHarvestDelay) external requiresAuth {
141        // A harvest delay of 0 makes harvests vulnerable to sandwich attacks.
142        require(newHarvestDelay != 0, "DELAY_CANNOT_BE_ZERO");
143
144        // A harvest delay longer than 1 year doesn't make sense.
145        require(newHarvestDelay <= 365 days, "DELAY_TOO_LONG");
146
147        // If the harvest delay is 0, meaning it has not been set before:
148        if (harvestDelay == 0) {
149            // We'll apply the update immediately.
150            harvestDelay = newHarvestDelay;
151
152            emit HarvestDelayUpdated(msg.sender, newHarvestDelay);
153        } else {
154            // We'll apply the update next harvest.
155            nextHarvestDelay = newHarvestDelay;
156
157            emit HarvestDelayUpdateScheduled(msg.sender, newHarvestDelay);
158        }
159    }
160
161    /*///////////////////////////////////////////////////////////////
162                       TARGET FLOAT CONFIGURATION
163    //////////////////////////////////////////////////////////////*/
164
165    /// @notice The desired percentage of the Vault's holdings to keep as float.
166    /// @dev A fixed point number where 1e18 represents 100% and 0 represents 0%.
167    uint256 public targetFloatPercent;
168
169    /// @notice Emitted when the target float percentage is updated.
170    /// @param user The authorized user who triggered the update.
171    /// @param newTargetFloatPercent The new target float percentage.
172    event TargetFloatPercentUpdated(address indexed user, uint256 newTargetFloatPercent);
173
174    /// @notice Set a new target float percentage.
175    /// @param newTargetFloatPercent The new target float percentage.
176    function setTargetFloatPercent(uint256 newTargetFloatPercent) external requiresAuth {
177        // A target float percentage over 100% doesn't make sense.
178        require(newTargetFloatPercent <= 1e18, "TARGET_TOO_HIGH");
179
180        // Update the target float percentage.
181        targetFloatPercent = newTargetFloatPercent;
182
183        emit TargetFloatPercentUpdated(msg.sender, newTargetFloatPercent);
184    }
185
186    /*///////////////////////////////////////////////////////////////
187                   UNDERLYING IS WETH CONFIGURATION
188    //////////////////////////////////////////////////////////////*/
189
190    /// @notice Whether the Vault should treat the underlying token as WETH compatible.
191    /// @dev If enabled the Vault will allow trusting strategies that accept Ether.
192    bool public underlyingIsWETH;
193
194    /// @notice Emitted when whether the Vault should treat the underlying as WETH is updated.
195    /// @param user The authorized user who triggered the update.
196    /// @param newUnderlyingIsWETH Whether the Vault nows treats the underlying as WETH.
197    event UnderlyingIsWETHUpdated(address indexed user, bool newUnderlyingIsWETH);
198
199    /// @notice Sets whether the Vault treats the underlying as WETH.
200    /// @param newUnderlyingIsWETH Whether the Vault should treat the underlying as WETH.
201    /// @dev The underlying token must have 18 decimals, to match Ether's decimal scheme.
202    function setUnderlyingIsWETH(bool newUnderlyingIsWETH) external requiresAuth {
203        // Ensure the underlying token's decimals match ETH if is WETH being set to true.
204        require(!newUnderlyingIsWETH || UNDERLYING.decimals() == 18, "WRONG_DECIMALS");
205
206        // Update whether the Vault treats the underlying as WETH.
207        underlyingIsWETH = newUnderlyingIsWETH;
208
209        emit UnderlyingIsWETHUpdated(msg.sender, newUnderlyingIsWETH);
210    }
211

JavaScript Tests